home *** CD-ROM | disk | FTP | other *** search
/ SGI Developer Toolbox 6.1 / SGI Developer Toolbox 6.1 - Disc 4.iso / lib / mathlib / libblas / src_original / ztbsv.f < prev    next >
Encoding:
Text File  |  1994-08-02  |  12.9 KB  |  385 lines
  1. *
  2. ************************************************************************
  3. *
  4.       SUBROUTINE ZTBSV ( UPLO, TRANS, DIAG, N, K, A, LDA, X, INCX )
  5. *     .. Scalar Arguments ..
  6.       INTEGER            INCX, K, LDA, N
  7.       CHARACTER*1        DIAG, TRANS, UPLO
  8. *     .. Array Arguments ..
  9.       COMPLEX*16         A( LDA, * ), X( * )
  10. *     ..
  11. *
  12. *  Purpose
  13. *  =======
  14. *
  15. *  ZTBSV  solves one of the systems of equations
  16. *
  17. *     A*x = b,   or   A'*x = b,   or   conjg( A' )*x = b,
  18. *
  19. *  where b and x are n element vectors and A is an n by n unit, or
  20. *  non-unit, upper or lower triangular band matrix, with ( k + 1 )
  21. *  diagonals.
  22. *
  23. *  No test for singularity or near-singularity is included in this
  24. *  routine. Such tests must be performed before calling this routine.
  25. *
  26. *  Parameters
  27. *  ==========
  28. *
  29. *  UPLO   - CHARACTER*1.
  30. *           On entry, UPLO specifies whether the matrix is an upper or
  31. *           lower triangular matrix as follows:
  32. *
  33. *              UPLO = 'U' or 'u'   A is an upper triangular matrix.
  34. *
  35. *              UPLO = 'L' or 'l'   A is a lower triangular matrix.
  36. *
  37. *           Unchanged on exit.
  38. *
  39. *  TRANS  - CHARACTER*1.
  40. *           On entry, TRANS specifies the equations to be solved as
  41. *           follows:
  42. *
  43. *              TRANS = 'N' or 'n'   A*x = b.
  44. *
  45. *              TRANS = 'T' or 't'   A'*x = b.
  46. *
  47. *              TRANS = 'C' or 'c'   conjg( A' )*x = b.
  48. *
  49. *           Unchanged on exit.
  50. *
  51. *  DIAG   - CHARACTER*1.
  52. *           On entry, DIAG specifies whether or not A is unit
  53. *           triangular as follows:
  54. *
  55. *              DIAG = 'U' or 'u'   A is assumed to be unit triangular.
  56. *
  57. *              DIAG = 'N' or 'n'   A is not assumed to be unit
  58. *                                  triangular.
  59. *
  60. *           Unchanged on exit.
  61. *
  62. *  N      - INTEGER.
  63. *           On entry, N specifies the order of the matrix A.
  64. *           N must be at least zero.
  65. *           Unchanged on exit.
  66. *
  67. *  K      - INTEGER.
  68. *           On entry with UPLO = 'U' or 'u', K specifies the number of
  69. *           super-diagonals of the matrix A.
  70. *           On entry with UPLO = 'L' or 'l', K specifies the number of
  71. *           sub-diagonals of the matrix A.
  72. *           K must satisfy  0 .le. K.
  73. *           Unchanged on exit.
  74. *
  75. *  A      - COMPLEX*16       array of DIMENSION ( LDA, n ).
  76. *           Before entry with UPLO = 'U' or 'u', the leading ( k + 1 )
  77. *           by n part of the array A must contain the upper triangular
  78. *           band part of the matrix of coefficients, supplied column by
  79. *           column, with the leading diagonal of the matrix in row
  80. *           ( k + 1 ) of the array, the first super-diagonal starting at
  81. *           position 2 in row k, and so on. The top left k by k triangle
  82. *           of the array A is not referenced.
  83. *           The following program segment will transfer an upper
  84. *           triangular band matrix from conventional full matrix storage
  85. *           to band storage:
  86. *
  87. *                 DO 20, J = 1, N
  88. *                    M = K + 1 - J
  89. *                    DO 10, I = MAX( 1, J - K ), J
  90. *                       A( M + I, J ) = matrix( I, J )
  91. *              10    CONTINUE
  92. *              20 CONTINUE
  93. *
  94. *           Before entry with UPLO = 'L' or 'l', the leading ( k + 1 )
  95. *           by n part of the array A must contain the lower triangular
  96. *           band part of the matrix of coefficients, supplied column by
  97. *           column, with the leading diagonal of the matrix in row 1 of
  98. *           the array, the first sub-diagonal starting at position 1 in
  99. *           row 2, and so on. The bottom right k by k triangle of the
  100. *           array A is not referenced.
  101. *           The following program segment will transfer a lower
  102. *           triangular band matrix from conventional full matrix storage
  103. *           to band storage:
  104. *
  105. *                 DO 20, J = 1, N
  106. *                    M = 1 - J
  107. *                    DO 10, I = J, MIN( N, J + K )
  108. *                       A( M + I, J ) = matrix( I, J )
  109. *              10    CONTINUE
  110. *              20 CONTINUE
  111. *
  112. *           Note that when DIAG = 'U' or 'u' the elements of the array A
  113. *           corresponding to the diagonal elements of the matrix are not
  114. *           referenced, but are assumed to be unity.
  115. *           Unchanged on exit.
  116. *
  117. *  LDA    - INTEGER.
  118. *           On entry, LDA specifies the first dimension of A as declared
  119. *           in the calling (sub) program. LDA must be at least
  120. *           ( k + 1 ).
  121. *           Unchanged on exit.
  122. *
  123. *  X      - COMPLEX*16       array of dimension at least
  124. *           ( 1 + ( n - 1 )*abs( INCX ) ).
  125. *           Before entry, the incremented array X must contain the n
  126. *           element right-hand side vector b. On exit, X is overwritten
  127. *           with the solution vector x.
  128. *
  129. *  INCX   - INTEGER.
  130. *           On entry, INCX specifies the increment for the elements of
  131. *           X. INCX must not be zero.
  132. *           Unchanged on exit.
  133. *
  134. *
  135. *  Level 2 Blas routine.
  136. *
  137. *  -- Written on 22-October-1986.
  138. *     Jack Dongarra, Argonne National Lab.
  139. *     Jeremy Du Croz, Nag Central Office.
  140. *     Sven Hammarling, Nag Central Office.
  141. *     Richard Hanson, Sandia National Labs.
  142. *
  143. *
  144. *     .. Parameters ..
  145.       COMPLEX*16         ZERO
  146.       PARAMETER        ( ZERO = ( 0.0D+0, 0.0D+0 ) )
  147. *     .. Local Scalars ..
  148.       COMPLEX*16         TEMP
  149.       INTEGER            I, INFO, IX, J, JX, KPLUS1, KX, L
  150.       LOGICAL            NOCONJ, NOUNIT
  151. *     .. External Functions ..
  152.       LOGICAL            LSAME
  153.       EXTERNAL           LSAME
  154. *     .. External Subroutines ..
  155.       EXTERNAL           XERBLA
  156. *     .. Intrinsic Functions ..
  157.       INTRINSIC          DCONJG, MAX, MIN
  158. *     ..
  159. *     .. Executable Statements ..
  160. *
  161. *     Test the input parameters.
  162. *
  163.       INFO = 0
  164.       IF     ( .NOT.LSAME( UPLO , 'U' ).AND.
  165.      $         .NOT.LSAME( UPLO , 'L' )      )THEN
  166.          INFO = 1
  167.       ELSE IF( .NOT.LSAME( TRANS, 'N' ).AND.
  168.      $         .NOT.LSAME( TRANS, 'T' ).AND.
  169.      $         .NOT.LSAME( TRANS, 'C' )      )THEN
  170.          INFO = 2
  171.       ELSE IF( .NOT.LSAME( DIAG , 'U' ).AND.
  172.      $         .NOT.LSAME( DIAG , 'N' )      )THEN
  173.          INFO = 3
  174.       ELSE IF( N.LT.0 )THEN
  175.          INFO = 4
  176.       ELSE IF( K.LT.0 )THEN
  177.          INFO = 5
  178.       ELSE IF( LDA.LT.( K + 1 ) )THEN
  179.          INFO = 7
  180.       ELSE IF( INCX.EQ.0 )THEN
  181.          INFO = 9
  182.       END IF
  183.       IF( INFO.NE.0 )THEN
  184.          CALL XERBLA( 'ZTBSV ', INFO )
  185.          RETURN
  186.       END IF
  187. *
  188. *     Quick return if possible.
  189. *
  190.       IF( N.EQ.0 )
  191.      $   RETURN
  192. *
  193.       NOCONJ = LSAME( TRANS, 'T' )
  194.       NOUNIT = LSAME( DIAG , 'N' )
  195. *
  196. *     Set up the start point in X if the increment is not unity. This
  197. *     will be  ( N - 1 )*INCX  too small for descending loops.
  198. *
  199.       IF( INCX.LE.0 )THEN
  200.          KX = 1 - ( N - 1 )*INCX
  201.       ELSE IF( INCX.NE.1 )THEN
  202.          KX = 1
  203.       END IF
  204. *
  205. *     Start the operations. In this version the elements of A are
  206. *     accessed by sequentially with one pass through A.
  207. *
  208.       IF( LSAME( TRANS, 'N' ) )THEN
  209. *
  210. *        Form  x := inv( A )*x.
  211. *
  212.          IF( LSAME( UPLO, 'U' ) )THEN
  213.             KPLUS1 = K + 1
  214.             IF( INCX.EQ.1 )THEN
  215.                DO 20, J = N, 1, -1
  216.                   IF( X( J ).NE.ZERO )THEN
  217.                      L = KPLUS1 - J
  218.                      IF( NOUNIT )
  219.      $                  X( J ) = X( J )/A( KPLUS1, J )
  220.                      TEMP = X( J )
  221.                      DO 10, I = J - 1, MAX( 1, J - K ), -1
  222.                         X( I ) = X( I ) - TEMP*A( L + I, J )
  223.    10                CONTINUE
  224.                   END IF
  225.    20          CONTINUE
  226.             ELSE
  227.                KX = KX + ( N - 1 )*INCX
  228.                JX = KX
  229.                DO 40, J = N, 1, -1
  230.                   KX = KX - INCX
  231.                   IF( X( JX ).NE.ZERO )THEN
  232.                      IX = KX
  233.                      L  = KPLUS1 - J
  234.                      IF( NOUNIT )
  235.      $                  X( JX ) = X( JX )/A( KPLUS1, J )
  236.                      TEMP = X( JX )
  237.                      DO 30, I = J - 1, MAX( 1, J - K ), -1
  238.                         X( IX ) = X( IX ) - TEMP*A( L + I, J )
  239.                         IX      = IX      - INCX
  240.    30                CONTINUE
  241.                   END IF
  242.                   JX = JX - INCX
  243.    40          CONTINUE
  244.             END IF
  245.          ELSE
  246.             IF( INCX.EQ.1 )THEN
  247.                DO 60, J = 1, N
  248.                   IF( X( J ).NE.ZERO )THEN
  249.                      L = 1 - J
  250.                      IF( NOUNIT )
  251.      $                  X( J ) = X( J )/A( 1, J )
  252.                      TEMP = X( J )
  253.                      DO 50, I = J + 1, MIN( N, J + K )
  254.                         X( I ) = X( I ) - TEMP*A( L + I, J )
  255.    50                CONTINUE
  256.                   END IF
  257.    60          CONTINUE
  258.             ELSE
  259.                JX = KX
  260.                DO 80, J = 1, N
  261.                   KX = KX + INCX
  262.                   IF( X( JX ).NE.ZERO )THEN
  263.                      IX = KX
  264.                      L  = 1  - J
  265.                      IF( NOUNIT )
  266.      $                  X( JX ) = X( JX )/A( 1, J )
  267.                      TEMP = X( JX )
  268.                      DO 70, I = J + 1, MIN( N, J + K )
  269.                         X( IX ) = X( IX ) - TEMP*A( L + I, J )
  270.                         IX      = IX      + INCX
  271.    70                CONTINUE
  272.                   END IF
  273.                   JX = JX + INCX
  274.    80          CONTINUE
  275.             END IF
  276.          END IF
  277.       ELSE
  278. *
  279. *        Form  x := inv( A' )*x  or  x := inv( conjg( A') )*x.
  280. *
  281.          IF( LSAME( UPLO, 'U' ) )THEN
  282.             KPLUS1 = K + 1
  283.             IF( INCX.EQ.1 )THEN
  284.                DO 110, J = 1, N
  285.                   TEMP = X( J )
  286.                   L    = KPLUS1 - J
  287.                   IF( NOCONJ )THEN
  288.                      DO 90, I = MAX( 1, J - K ), J - 1
  289.                         TEMP = TEMP - A( L + I, J )*X( I )
  290.    90                CONTINUE
  291.                      IF( NOUNIT )
  292.      $                  TEMP = TEMP/A( KPLUS1, J )
  293.                   ELSE
  294.                      DO 100, I = MAX( 1, J - K ), J - 1
  295.                         TEMP = TEMP - DCONJG( A( L + I, J ) )*X( I )
  296.   100                CONTINUE
  297.                      IF( NOUNIT )
  298.      $                  TEMP = TEMP/DCONJG( A( KPLUS1, J ) )
  299.                   END IF
  300.                   X( J ) = TEMP
  301.   110          CONTINUE
  302.             ELSE
  303.                JX = KX
  304.                DO 140, J = 1, N
  305.                   TEMP = X( JX )
  306.                   IX   = KX
  307.                   L    = KPLUS1  - J
  308.                   IF( NOCONJ )THEN
  309.                      DO 120, I = MAX( 1, J - K ), J - 1
  310.                         TEMP = TEMP - A( L + I, J )*X( IX )
  311.                         IX   = IX   + INCX
  312.   120                CONTINUE
  313.                      IF( NOUNIT )
  314.      $                  TEMP = TEMP/A( KPLUS1, J )
  315.                   ELSE
  316.                      DO 130, I = MAX( 1, J - K ), J - 1
  317.                         TEMP = TEMP - DCONJG( A( L + I, J ) )*X( IX )
  318.                         IX   = IX   + INCX
  319.   130                CONTINUE
  320.                      IF( NOUNIT )
  321.      $                  TEMP = TEMP/DCONJG( A( KPLUS1, J ) )
  322.                   END IF
  323.                   X( JX ) = TEMP
  324.                   JX      = JX   + INCX
  325.                   IF( J.GT.K )
  326.      $               KX = KX + INCX
  327.   140          CONTINUE
  328.             END IF
  329.          ELSE
  330.             IF( INCX.EQ.1 )THEN
  331.                DO 170, J = N, 1, -1
  332.                   TEMP = X( J )
  333.                   L    = 1      - J
  334.                   IF( NOCONJ )THEN
  335.                      DO 150, I = MIN( N, J + K ), J + 1, -1
  336.                         TEMP = TEMP - A( L + I, J )*X( I )
  337.   150                CONTINUE
  338.                      IF( NOUNIT )
  339.      $                  TEMP = TEMP/A( 1, J )
  340.                   ELSE
  341.                      DO 160, I = MIN( N, J + K ), J + 1, -1
  342.                         TEMP = TEMP - DCONJG( A( L + I, J ) )*X( I )
  343.   160                CONTINUE
  344.                      IF( NOUNIT )
  345.      $                  TEMP = TEMP/DCONJG( A( 1, J ) )
  346.                   END IF
  347.                   X( J ) = TEMP
  348.   170          CONTINUE
  349.             ELSE
  350.                KX = KX + ( N - 1 )*INCX
  351.                JX = KX
  352.                DO 200, J = N, 1, -1
  353.                   TEMP = X( JX )
  354.                   IX   = KX
  355.                   L    = 1       - J
  356.                   IF( NOCONJ )THEN
  357.                      DO 180, I = MIN( N, J + K ), J + 1, -1
  358.                         TEMP = TEMP - A( L + I, J )*X( IX )
  359.                         IX   = IX   - INCX
  360.   180                CONTINUE
  361.                      IF( NOUNIT )
  362.      $                  TEMP = TEMP/A( 1, J )
  363.                   ELSE
  364.                      DO 190, I = MIN( N, J + K ), J + 1, -1
  365.                         TEMP = TEMP - DCONJG( A( L + I, J ) )*X( IX )
  366.                         IX   = IX   - INCX
  367.   190                CONTINUE
  368.                      IF( NOUNIT )
  369.      $                  TEMP = TEMP/DCONJG( A( 1, J ) )
  370.                   END IF
  371.                   X( JX ) = TEMP
  372.                   JX      = JX   - INCX
  373.                   IF( ( N - J ).GE.K )
  374.      $               KX = KX - INCX
  375.   200          CONTINUE
  376.             END IF
  377.          END IF
  378.       END IF
  379. *
  380.       RETURN
  381. *
  382. *     End of ZTBSV .
  383. *
  384.       END
  385.